Kernel/linux-next
1
0
Fork 0
mirror of https://git.kernel.org/pub/scm/linux/kernel/git/next/linux-next.git synced 2024-12-29 17:22:07 +00:00
Code Issues Actions Packages Projects Releases Wiki Activity

Merge branch 'selftests-net-packetdrill-import-multiple-tests'

Browse Source 
Soham Chakradeo says:

====================
selftests/net: packetdrill: import multiple tests

Import tests for the following features (folder names in brackets):
ECN (ecn) : RFC 3168
Close (close) : RFC 9293
TCP_INFO (tcp_info) : RFC 9293
Fast recovery (fast_recovery) : RFC 5681
Timestamping (timestamping) : RFC 1323
Nagle (nagle) : RFC 896
Selective Acknowledgments (sack) : RFC 2018
Recent Timestamp (ts_recent) : RFC 1323
Send file (sendfile)
Syscall bad arg (syscall_bad_arg)
Validate (validate)
Blocking (blocking)
Splice (splice)
End of record (eor)
Limited transmit (limited_transmit)

Procedure to import and test the packetdrill tests into upstream linux
is explained in the first patch of this series

These tests have many authors. We only import them here from
github.com/google/packetdrill. Thanks to the following authors fo their
contributions over the years to these tests: Neal Cardwell, Shuo Chen,
Yuchung Cheng, Jerry Chu, Eric Dumazet, Luke Hsiao, Priyaranjan Jha,
Chonggang Li, Tanner Love, John Sperbeck, Wei Wang and Maciej
Żenczykowski. For more info see the original github commits, such as
https://github.com/google/packetdrill/commit/8229c94928ac.
====================

Link: https://patch.msgid.link/20241217185203.297935-1-sohamch.kernel@gmail.com
Signed-off-by: Jakub Kicinski <kuba@kernel.org>
This commit is contained in:
Jakub Kicinski 2024-12-18 10:01:33 -08:00
commit 4b252f2dab
42 changed files with 1844 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

18
tools/testing/selftests/net/packetdrill/tcp_blocking_blocking-accept.pkt Normal file
View File

@ -0,0 +1,18 @@
// SPDX-License-Identifier: GPL-2.0
// Test for blocking accept.
`./defaults.sh`
// Establish a connection.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0...0.200 accept(3, ..., ...) = 4
+.1 < S 0:0(0) win 32792 <mss 1000,nop,wscale 7>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,wscale 8>
+.1 < . 1:1(0) ack 1 win 257
+.1 write(4, ..., 2000) = 2000
+0 > P. 1:2001(2000) ack 1

13
tools/testing/selftests/net/packetdrill/tcp_blocking_blocking-connect.pkt Normal file
View File

@ -0,0 +1,13 @@
// SPDX-License-Identifier: GPL-2.0
// Test for blocking connect.
`./defaults.sh`
// Establish a connection.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+.1...0.200 connect(3, ..., ...) = 0
+0 > S 0:0(0) <mss 1460,sackOK,TS val 100 ecr 0,nop,wscale 8>
+.1 < S. 0:0(0) ack 1 win 5792 <mss 1460,nop,wscale 2,nop,nop,sackOK>
+0 > . 1:1(0) ack 1

29
tools/testing/selftests/net/packetdrill/tcp_blocking_blocking-read.pkt Normal file
View File

@ -0,0 +1,29 @@
// SPDX-License-Identifier: GPL-2.0
// Test for blocking read.
--tolerance_usecs=10000
`./defaults.sh`
// Establish a connection.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+.1 < S 0:0(0) win 32792 <mss 1000,nop,wscale 7>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,wscale 8>
+.1 < . 1:1(0) ack 1 win 257
+0 accept(3, ..., ...) = 4
+0...0.100 read(4, ..., 2000) = 2000
+.1 < P. 1:2001(2000) ack 1 win 257
+0 > . 1:1(0) ack 2001
+.1...0.200 read(4, ..., 2000) = 2000
+.1 < P. 2001:4001(2000) ack 1 win 257
+0 > . 1:1(0) ack 4001
+.1 < P. 4001:6001(2000) ack 1 win 257
+0 > . 1:1(0) ack 6001
+0...0.000 read(4, ..., 1000) = 1000
+0...0.000 read(4, ..., 1000) = 1000

35
tools/testing/selftests/net/packetdrill/tcp_blocking_blocking-write.pkt Normal file
View File

@ -0,0 +1,35 @@
// SPDX-License-Identifier: GPL-2.0
// Test for blocking write.
--tolerance_usecs=10000
`./defaults.sh
./set_sysctls.py /proc/sys/net/ipv4/tcp_min_tso_segs=10
`
// Establish a connection.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+.1 < S 0:0(0) win 50000 <mss 1000,nop,wscale 0>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,wscale 8>
+.1 < . 1:1(0) ack 1 win 50000
+0 accept(3, ..., ...) = 4
// Kernel doubles our value -> sk->sk_sndbuf is set to 42000
+0 setsockopt(4, SOL_SOCKET, SO_SNDBUF, [21000], 4) = 0
+0 getsockopt(4, SOL_SOCKET, SO_SNDBUF, [42000], [4]) = 0
// A write of 60000 does not block.
+0...0.300 write(4, ..., 61000) = 61000 // this write() blocks
+.1 < . 1:1(0) ack 10001 win 50000
+.1 < . 1:1(0) ack 30001 win 50000
// This ACK should wakeup the write(). An ACK of 35001 does not.
+.1 < . 1:1(0) ack 36001 win 50000
// Reset to sysctls defaults.
`/tmp/sysctl_restore_${PPID}.sh`

23
tools/testing/selftests/net/packetdrill/tcp_close_close-local-close-then-remote-fin.pkt Normal file
View File

@ -0,0 +1,23 @@
// SPDX-License-Identifier: GPL-2.0
// Test basic connection teardown where local process closes first:
// the local process calls close() first, so we send a FIN, and receive an ACK.
// Then we receive a FIN and ACK it.
`./defaults.sh`
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+.01...0.011 connect(3, ..., ...) = 0
+0 > S 0:0(0) <...>
+0 < S. 0:0(0) ack 1 win 32768 <mss 1000,nop,wscale 6,nop,nop,sackOK>
+0 > . 1:1(0) ack 1
+0 write(3, ..., 1000) = 1000
+0 > P. 1:1001(1000) ack 1
+0 < . 1:1(0) ack 1001 win 257
+0 close(3) = 0
+0 > F. 1001:1001(0) ack 1
+0 < . 1:1(0) ack 1002 win 257
+0 < F. 1:1(0) ack 1002 win 257
+0 > . 1002:1002(0) ack 2

21
tools/testing/selftests/net/packetdrill/tcp_close_close-on-syn-sent.pkt Normal file
View File

@ -0,0 +1,21 @@
// SPDX-License-Identifier: GPL-2.0
// Test to make sure no RST is being sent when close()
// is called on a socket with SYN_SENT state.
`./defaults.sh`
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 fcntl(3, F_SETFL, O_RDWR|O_NONBLOCK) = 0
+0 connect(3, ..., ...) = -1 EINPROGRESS (Operation now in progress)
+0 > S 0:0(0) <...>
// Application decideds to close the socket in SYN_SENT state
// Make sure no RST is sent after close().
+0 close(3) = 0
// Receive syn-ack to trigger the send side packet examination:
// If a RESET were sent right after close(), it would have failed with
// a mismatched timestamp.
+.1 < S. 0:0(0) ack 1 win 32000 <mss 1460,nop,wscale 7>
+0 > R 1:1(0)

36
tools/testing/selftests/net/packetdrill/tcp_close_close-remote-fin-then-close.pkt Normal file
View File

@ -0,0 +1,36 @@
// SPDX-License-Identifier: GPL-2.0
// Verify behavior for the sequence: remote side sends FIN, then we close().
// Since the remote side (client) closes first, we test our LAST_ACK code path.
`./defaults.sh`
// Initialize a server socket.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0 < S 0:0(0) win 32792 <mss 1000,sackOK,nop,nop,nop,wscale 7>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,nop,sackOK,nop,wscale 8>
+0 < . 1:1(0) ack 1 win 257
+0 accept(3, ..., ...) = 4
// Client closes first.
+.01 < F. 1:1(0) ack 1 win 257
+0 > . 1:1(0) ack 2
// App notices that client closed.
+0 read(4, ..., 1000) = 0
// Then we close.
+.01 close(4) = 0
+0 > F. 1:1(0) ack 2
// Client ACKs our FIN.
+.01 < . 2:2(0) ack 2 win 257
// Verify that we send RST in response to any incoming segments
// (because the kernel no longer has any record of this socket).
+.01 < . 2:2(0) ack 2 win 257
+0 > R 2:2(0)

21
tools/testing/selftests/net/packetdrill/tcp_ecn_ecn-uses-ect0.pkt Normal file
View File

@ -0,0 +1,21 @@
// SPDX-License-Identifier: GPL-2.0
// Test ECN: verify that Linux TCP ECN sending code uses ECT0 (not ECT1).
//
`./defaults.sh
sysctl -q net.ipv4.tcp_ecn=1 # fully enabled
`
// Initialize connection
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 4
// ECN handshake: send EW flags in SYN packet, E flag in SYN-ACK response
+.002 ... 0.004 connect(4, ..., ...) = 0
+0 > SEW 0:0(0) <mss 1460,sackOK,TS val 100 ecr 0,nop,wscale 8>
+.002 < SE. 0:0(0) ack 1 win 32767 <mss 1000,nop,wscale 6,nop,nop,sackOK>
+0 > . 1:1(0) ack 1
// Write 1 MSS.
+.002 write(4, ..., 1000) = 1000
// Send 1 MSS with ect0.
+0 > [ect0] P. 1:1001(1000) ack 1

38
tools/testing/selftests/net/packetdrill/tcp_eor_no-coalesce-large.pkt Normal file
View File

@ -0,0 +1,38 @@
// SPDX-License-Identifier: GPL-2.0
// Test TCP does not append any data from consequent writes to the tail
// skb created for the chunk. The large chunk itself should be packetized as
// usual.
`./defaults.sh
`
// Initialize connection
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0 < S 0:0(0) win 32792 <mss 1000,sackOK,nop,nop,nop,wscale 10>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,nop,sackOK,nop,wscale 8>
+.01 < . 1:1(0) ack 1 win 514
+0 accept(3, ..., ...) = 4
// Write a 10400B chunk to fill the ICW, and have a 400 byte skb sitting on
// the tail.
+0 write(4, ..., 10400) = 10400
// Write another 10040B chunk with no coalescing options.
+0 send(4, ..., 10400, MSG_EOR) = 10400
// Write a 2KB chunk. This chunk should not be appended to the packets created
// the previous chunk.
+0 write(4, ..., 2000) = 2000
+0 > P. 1:10001(10000) ack 1
+.001 < . 1:1(0) ack 10001 win 514
// Now we have enough room to send out the 2 x 400B packets out.
+0 > P. 10001:20801(10800) ack 1
+.001 < . 1:1(0) ack 20801 win 514
// This 2KB packet should be sent alone.
+0 > P. 20801:22801(2000) ack 1
+.001 < . 1:1(0) ack 22801 win 514

72
tools/testing/selftests/net/packetdrill/tcp_eor_no-coalesce-retrans.pkt Normal file
View File

@ -0,0 +1,72 @@
// SPDX-License-Identifier: GPL-2.0
// Test TCP does not append any data from consequent writes to the tail
// skb created for the chunk. Also, when packets are retransmitted, they
// will not be coalesce into the same skb.
`./defaults.sh
`
// Initialize connection
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0 < S 0:0(0) win 32792 <mss 1000,sackOK,nop,nop,nop,wscale 10>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,nop,sackOK,nop,wscale 8>
+.01 < . 1:1(0) ack 1 win 514
+0 accept(3, ..., ...) = 4
// Write a 10400B chunk to fill the ICW, and have a 400 byte skb sitting on
// the tail.
+0 write(4, ..., 10400) = 10400
// Write 10 400B chunks with no coalescing options.
+0 send(4, ..., 400, MSG_EOR) = 400
+0 send(4, ..., 400, MSG_EOR) = 400
+0 send(4, ..., 400, MSG_EOR) = 400
+0 send(4, ..., 400, MSG_EOR) = 400
+0 send(4, ..., 400, MSG_EOR) = 400
+0 send(4, ..., 400, MSG_EOR) = 400
+0 send(4, ..., 400, MSG_EOR) = 400
+0 send(4, ..., 400, MSG_EOR) = 400
+0 send(4, ..., 400, MSG_EOR) = 400
+0 send(4, ..., 400, MSG_EOR) = 400
// This chunk should not be appended to the skbs created for the previous chunk.
+0 write(4, ..., 10000) = 10000
+0 > P. 1:10001(10000) ack 1
+.001 < . 1:1(0) ack 10001 win 514
// Now we have enough room to send out the 2 x 400B packets out.
+0 > P. 10001:10801(800) ack 1
// The 9 remaining 400B chunks should be sent as individual packets.
+0 > P. 10801:11201(400) ack 1
+0 > P. 11201:11601(400) ack 1
+0 > P. 11601:12001(400) ack 1
+0 > P. 12001:12401(400) ack 1
+0 > P. 12401:12801(400) ack 1
+0 > P. 12801:13201(400) ack 1
+0 > P. 13201:13601(400) ack 1
+0 > P. 13601:14001(400) ack 1
+0 > P. 14001:14401(400) ack 1
// The last 10KB chunk should be sent separately.
+0 > P. 14401:24401(10000) ack 1
+.001 < . 1:1(0) ack 10401 win 514
+.001 < . 1:1(0) ack 10801 win 514
+.001 < . 1:1(0) ack 11201 win 514
+.001 < . 1:1(0) ack 11601 win 514
+.001 < . 1:1(0) ack 12001 win 514 <sack 13201:14401,nop,nop>
// TCP should fill the hole but no coalescing should happen, and all
// retransmissions should be sent out as individual packets.
// Note : This is timeout based retransmit.
// Do not put +0 here or flakes will come back.
+.004~+.008 > P. 12001:12401(400) ack 1
+.001 < . 1:1(0) ack 12401 win 514 <sack 13201:14401,nop,nop>
+0 > P. 12401:12801(400) ack 1
+0 > P. 12801:13201(400) ack 1
+.001 < . 1:1(0) ack 12801 win 514 <sack 13201:14401,nop,nop>
+.001 < . 1:1(0) ack 14401 win 514
+.001 < . 1:1(0) ack 24401 win 514

36
tools/testing/selftests/net/packetdrill/tcp_eor_no-coalesce-small.pkt Normal file
View File

@ -0,0 +1,36 @@
// SPDX-License-Identifier: GPL-2.0
// Test TCP does not append any data from consequent writes to the tail
// skb created for the chunk.
`./defaults.sh
`
// Initialize connection
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0 < S 0:0(0) win 32792 <mss 1000,sackOK,nop,nop,nop,wscale 10>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,nop,sackOK,nop,wscale 8>
+.01 < . 1:1(0) ack 1 win 514
+0 accept(3, ..., ...) = 4
// Write a 10400B chunk to fill the ICW, and have a 400 byte skb sitting on
// the tail.
+0 write(4, ..., 10400) = 10400
// Write a 400B chunk with no coalescing options.
+0 send(4, ..., 400, MSG_EOR) = 400
// This chunk should not be appended to the skbs created for the previous chunk.
+0 write(4, ..., 10000) = 10000
+0 > P. 1:10001(10000) ack 1
+.001 < . 1:1(0) ack 10001 win 514
// Now we have enough room to send out the 2 x 400B packets out.
+0 > P. 10001:10801(800) ack 1
+0 > P. 10801:20801(10000) ack 1
+.001 < . 1:1(0) ack 10401 win 514
+.001 < . 1:1(0) ack 10801 win 514
+.001 < . 1:1(0) ack 20801 win 514

66
tools/testing/selftests/net/packetdrill/tcp_eor_no-coalesce-subsequent.pkt Normal file
View File

@ -0,0 +1,66 @@
// SPDX-License-Identifier: GPL-2.0
// Test TCP does not append any data from consequent writes to the tail
// skb created for the chunk even though we have 10 back-to-back small
// writes.
`./defaults.sh
`
// Initialize connection
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0 < S 0:0(0) win 32792 <mss 1000,sackOK,nop,nop,nop,wscale 10>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,nop,sackOK,nop,wscale 8>
+.01 < . 1:1(0) ack 1 win 514
+0 accept(3, ..., ...) = 4
// Write a 10400B chunk to fill the ICW, and have a 400 byte skb sitting on
// the tail.
+0 write(4, ..., 10400) = 10400
// Write 10 400B chunks with no coalescing options.
+0 send(4, ..., 400, MSG_EOR) = 400
+0 send(4, ..., 400, MSG_EOR) = 400
+0 send(4, ..., 400, MSG_EOR) = 400
+0 send(4, ..., 400, MSG_EOR) = 400
+0 send(4, ..., 400, MSG_EOR) = 400
+0 send(4, ..., 400, MSG_EOR) = 400
+0 send(4, ..., 400, MSG_EOR) = 400
+0 send(4, ..., 400, MSG_EOR) = 400
+0 send(4, ..., 400, MSG_EOR) = 400
+0 send(4, ..., 400, MSG_EOR) = 400
// This chunk should not be appended to the skbs created for the previous chunk.
+0 write(4, ..., 10000) = 10000
+0 > P. 1:10001(10000) ack 1
+.001 < . 1:1(0) ack 10001 win 514
// Now we have enough room to send out the 2 x 400B packets out.
+0 > P. 10001:10801(800) ack 1
// The 9 remaining 400B chunks should be sent as individual packets.
+0 > P. 10801:11201(400) ack 1
+0 > P. 11201:11601(400) ack 1
+0 > P. 11601:12001(400) ack 1
+0 > P. 12001:12401(400) ack 1
+0 > P. 12401:12801(400) ack 1
+0 > P. 12801:13201(400) ack 1
+0 > P. 13201:13601(400) ack 1
+0 > P. 13601:14001(400) ack 1
+0 > P. 14001:14401(400) ack 1
// The last 10KB chunk should be sent separately.
+0 > P. 14401:24401(10000) ack 1
+.001 < . 1:1(0) ack 10401 win 514
+.001 < . 1:1(0) ack 10801 win 514
+.001 < . 1:1(0) ack 11201 win 514
+.001 < . 1:1(0) ack 11601 win 514
+.001 < . 1:1(0) ack 12001 win 514
+.001 < . 1:1(0) ack 12401 win 514
+.001 < . 1:1(0) ack 12801 win 514
+.001 < . 1:1(0) ack 13201 win 514
+.001 < . 1:1(0) ack 13601 win 514
+.001 < . 1:1(0) ack 14001 win 514
+.001 < . 1:1(0) ack 14401 win 514
+.001 < . 1:1(0) ack 24401 win 514

72
tools/testing/selftests/net/packetdrill/tcp_fast_recovery_prr-ss-10pkt-lost-1.pkt Normal file
View File

@ -0,0 +1,72 @@
// SPDX-License-Identifier: GPL-2.0
// Test PRR-slowstart implementation.
// In this variant we test a simple case where in-flight == ssthresh
// all the way through recovery, so during fast recovery we send one segment
// for each segment SACKed/ACKed.
// Set up config.
`./defaults.sh`
// Establish a connection.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+.1 < S 0:0(0) win 32792 <mss 1000,sackOK,nop,nop,nop,wscale 7>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,nop,sackOK,nop,wscale 8>
// RTT 100ms
+.1 < . 1:1(0) ack 1 win 320
+0 accept(3, ..., ...) = 4
// Send 10 data segments.
+0 write(4, ..., 10000) = 10000
+0 > P. 1:10001(10000) ack 1
// Lost packet 1:1001.
+.11 < . 1:1(0) ack 1 win 320 <sack 1001:2001,nop,nop>
+.01 < . 1:1(0) ack 1 win 320 <sack 1001:3001,nop,nop>
+.01 < . 1:1(0) ack 1 win 320 <sack 1001:4001,nop,nop>
// Enter fast recovery.
+0 > . 1:1001(1000) ack 1
+.01 %{
assert tcpi_ca_state == TCP_CA_Recovery, tcpi_ca_state
assert tcpi_snd_cwnd == 7, tcpi_snd_cwnd
assert tcpi_snd_ssthresh == 7, tcpi_snd_ssthresh
}%
// Write some more, which we will send 1 MSS at a time,
// as in-flight segments are SACKed or ACKed.
+.01 write(4, ..., 7000) = 7000
+.01 < . 1:1(0) ack 1 win 320 <sack 1001:5001,nop,nop>
+0 > . 10001:11001(1000) ack 1
+.01 < . 1:1(0) ack 1 win 320 <sack 1001:6001,nop,nop>
+0 > . 11001:12001(1000) ack 1
+.01 < . 1:1(0) ack 1 win 320 <sack 1001:7001,nop,nop>
+0 > . 12001:13001(1000) ack 1
+.01 < . 1:1(0) ack 1 win 320 <sack 1001:8001,nop,nop>
+0 > . 13001:14001(1000) ack 1
+.01 < . 1:1(0) ack 1 win 320 <sack 1001:9001,nop,nop>
+0 > . 14001:15001(1000) ack 1
+.01 < . 1:1(0) ack 1 win 320 <sack 1001:10001,nop,nop>
+0 > . 15001:16001(1000) ack 1
+.02 < . 1:1(0) ack 10001 win 320
+0 > P. 16001:17001(1000) ack 1
// Leave fast recovery.
+.01 %{
assert tcpi_ca_state == TCP_CA_Open, tcpi_ca_state
assert tcpi_snd_cwnd == 7, tcpi_snd_cwnd
assert tcpi_snd_ssthresh == 7, tcpi_snd_ssthresh
}%
+.03 < . 1:1(0) ack 12001 win 320
+.02 < . 1:1(0) ack 14001 win 320
+.02 < . 1:1(0) ack 16001 win 320
+.02 < . 1:1(0) ack 17001 win 320

50
tools/testing/selftests/net/packetdrill/tcp_fast_recovery_prr-ss-30pkt-lost-1_4-11_16.pkt Normal file
View File

@ -0,0 +1,50 @@
// SPDX-License-Identifier: GPL-2.0
// Test PRR-slowstart implementation. The sender sends 20 packets. Packet
// 1 to 4, and 11 to 16 are dropped.
`./defaults.sh`
// Establish a connection.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0 < S 0:0(0) win 32792 <mss 1000,sackOK,nop,nop,nop,wscale 7>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,nop,sackOK,nop,wscale 8>
+.01 < . 1:1(0) ack 1 win 320
+0 accept(3, ..., ...) = 4
// Write 20 data segments.
+0 write(4, ..., 20000) = 20000
+0 > P. 1:10001(10000) ack 1
// Receive first DUPACK, entering PRR part
+.01 < . 1:1(0) ack 1 win 320 <sack 4001:5001,nop,nop>
+0 > . 10001:11001(1000) ack 1
+.002 < . 1:1(0) ack 1 win 320 <sack 4001:6001,nop,nop>
+0 > . 11001:12001(1000) ack 1
+.002 < . 1:1(0) ack 1 win 320 <sack 4001:7001,nop,nop>
+0 > . 1:1001(1000) ack 1
+.002 < . 1:1(0) ack 1 win 320 <sack 4001:8001,nop,nop>
+0 > . 1001:2001(1000) ack 1
+.002 < . 1:1(0) ack 1 win 320 <sack 4001:9001,nop,nop>
+0 > . 2001:3001(1000) ack 1
+.002 < . 1:1(0) ack 1 win 320 <sack 4001:10001,nop,nop>
+0 > . 3001:4001(1000) ack 1
// Enter PRR CRB
+.002 < . 1:1(0) ack 1 win 320 <sack 4001:11001,nop,nop>
+0 > . 12001:13001(1000) ack 1
+.002 < . 1:1(0) ack 1 win 320 <sack 4001:12001,nop,nop>
+0 > . 13001:14001(1000) ack 1
// Enter PRR slow start
+.01 < . 1:1(0) ack 1001 win 320 <sack 4001:12001,nop,nop>
+0 > P. 14001:16001(2000) ack 1
+.002 < . 1:1(0) ack 1001 win 320 <sack 2001:12001,nop,nop>
+0 > . 1001:2001(1000) ack 1
+0 > . 16001:17001(1000) ack 1
// inflight reaches ssthresh, goes into packet conservation mode
+.002 < . 1:1(0) ack 1001 win 320 <sack 2001:13001,nop,nop>
+0 > . 17001:18001(1000) ack 1
+.002 < . 1:1(0) ack 1001 win 320 <sack 2001:14001,nop,nop>
+0 > . 18001:19001(1000) ack 1

43
tools/testing/selftests/net/packetdrill/tcp_fast_recovery_prr-ss-30pkt-lost1_4.pkt Normal file
View File

@ -0,0 +1,43 @@
// SPDX-License-Identifier: GPL-2.0
// Test PRR-slowstart implementation. The sender sends 20 packets. Packet
// 1 to 4 are lost. The sender writes another 10 packets.
`./defaults.sh`
// Establish a connection.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0 < S 0:0(0) win 32792 <mss 1000,sackOK,nop,nop,nop,wscale 7>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,nop,sackOK,nop,wscale 8>
+.01 < . 1:1(0) ack 1 win 320
+0 accept(3, ..., ...) = 4
// Send 20 data segments.
+0 write(4, ..., 10000) = 10000
+0 > P. 1:10001(10000) ack 1
// Lost packet 1,2,3,4
+.01 < . 1:1(0) ack 1 win 320 <sack 4001:5001,nop,nop>
+.002 < . 1:1(0) ack 1 win 320 <sack 4001:6001,nop,nop>
+0 < . 1:1(0) ack 1 win 320 <sack 4001:7001,nop,nop>
+0 > . 1:1001(1000) ack 1
+0 < . 1:1(0) ack 1 win 320 <sack 4001:8001,nop,nop>
+0 > . 1001:2001(1000) ack 1
+0 < . 1:1(0) ack 1 win 320 <sack 4001:9001,nop,nop>
+0 > . 2001:3001(1000) ack 1
+0 < . 1:1(0) ack 1 win 320 <sack 4001:10001,nop,nop>
+0 > . 3001:4001(1000) ack 1
// Receiver ACKs all data.
+.01 < . 1:1(0) ack 1001 win 320 <sack 4001:10001,nop,nop>
+0 < . 1:1(0) ack 2001 win 320 <sack 4001:10001,nop,nop>
+0 < . 1:1(0) ack 3001 win 320 <sack 4001:10001,nop,nop>
+0 < . 1:1(0) ack 10001 win 320
// Writes another 10 packets, which the ssthresh*mss amount
// should be sent right away
+.01 write(4, ..., 10000) = 10000
+0 > . 10001:17001(7000) ack 1

41
tools/testing/selftests/net/packetdrill/tcp_fast_recovery_prr-ss-ack-below-snd_una-cubic.pkt Normal file
View File

@ -0,0 +1,41 @@
// SPDX-License-Identifier: GPL-2.0
// Test PRR-slowstart implementation.
// In this variant we verify that the sender uses SACK info on an ACK
// below snd_una.
// Set up config.
`./defaults.sh`
// Establish a connection.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0 < S 0:0(0) win 32792 <mss 1000,sackOK,nop,nop,nop,wscale 8>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,nop,sackOK,nop,wscale 8>
// RTT 10ms
+.01 < . 1:1(0) ack 1 win 320
+0 accept(3, ..., ...) = 4
// Send 10 data segments.
+0 write(4, ..., 10000) = 10000
+0 > P. 1:10001(10000) ack 1
// Lost packet 1:1001,4001:5001,7001:8001.
+.01 < . 1:1(0) ack 1 win 320 <sack 1001:2001,nop,nop>
+0 < . 1:1(0) ack 1 win 320 <sack 1001:3001,nop,nop>
+0 < . 1:1(0) ack 1 win 320 <sack 1001:3001 8001:9001,nop,nop>
+0 > . 1:1001(1000) ack 1
+.012 < . 1:1(0) ack 4001 win 320 <sack 8001:9001,nop,nop>
+0 > . 4001:7001(3000) ack 1
+0 write(4, ..., 10000) = 10000
// The following ACK was reordered - delayed so that it arrives with
// an ACK field below snd_una. Here we check that the newly-SACKed
// 2MSS at 5001:7001 cause us to send out 2 more MSS.
+.002 < . 1:1(0) ack 3001 win 320 <sack 5001:7001,nop,nop>
+0 > . 7001:8001(1000) ack 1
+0 > . 10001:11001(1000) ack 1

53
tools/testing/selftests/net/packetdrill/tcp_limited_transmit_limited-transmit-no-sack.pkt Normal file
View File

@ -0,0 +1,53 @@
// SPDX-License-Identifier: GPL-2.0
// Test RFC 3042 "Limited Transmit": "sending a new data segment in
// response to each of the first two duplicate acknowledgments that
// arrive at the sender".
// This variation tests a receiver that doesn't support SACK.
`./defaults.sh`
// Establish a connection.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+.1 < S 0:0(0) win 32792 <mss 1000,nop,wscale 7>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,wscale 8>
+.1 < . 1:1(0) ack 1 win 320
+0 accept(3, ..., ...) = 4
// Write some data, and send the initial congestion window.
+0 write(4, ..., 15000) = 15000
+0 > P. 1:10001(10000) ack 1
// Limited transmit: on first dupack, send a new data segment.
+.11 < . 1:1(0) ack 1 win 320
+0 > . 10001:11001(1000) ack 1
// Limited transmit: on second dupack, send a new data segment.
+.01 < . 1:1(0) ack 1 win 320
+0 > . 11001:12001(1000) ack 1
// It turned out to be reordering, not loss.
// We have one packet newly acked (1001:3001 were DUP-ACK'd)
// So we revert state back to Open. Slow start cwnd from 10 to 11
// and send 11 - 9 = 2 packets
+.01 < . 1:1(0) ack 3001 win 320
+0 > P. 12001:14001(2000) ack 1
+.02 < . 1:1(0) ack 5001 win 320
+0 > P. 14001:15001(1000) ack 1
// Client gradually ACKs all data.
+.02 < . 1:1(0) ack 7001 win 320
+.02 < . 1:1(0) ack 9001 win 320
+.02 < . 1:1(0) ack 11001 win 320
+.02 < . 1:1(0) ack 13001 win 320
+.02 < . 1:1(0) ack 15001 win 320
// Clean up.
+.17 close(4) = 0
+0 > F. 15001:15001(0) ack 1
+.1 < F. 1:1(0) ack 15002 win 257
+0 > . 15002:15002(0) ack 2

50
tools/testing/selftests/net/packetdrill/tcp_limited_transmit_limited-transmit-sack.pkt Normal file
View File

@ -0,0 +1,50 @@
// SPDX-License-Identifier: GPL-2.0
// Test RFC 3042 "Limited Transmit": "sending a new data segment in
// response to each of the first two duplicate acknowledgments that
// arrive at the sender".
// This variation tests a receiver that supports SACK.
`./defaults.sh`
// Establish a connection.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+.1 < S 0:0(0) win 32792 <mss 1000,sackOK,nop,nop,nop,wscale 7>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,nop,sackOK,nop,wscale 8>
+.1 < . 1:1(0) ack 1 win 320
+0 accept(3, ..., ...) = 4
// Write some data, and send the initial congestion window.
+0 write(4, ..., 15000) = 15000
+0 > P. 1:10001(10000) ack 1
// Limited transmit: on first dupack, send a new data segment.
+.11 < . 1:1(0) ack 1 win 320 <sack 1001:2001,nop,nop>
+0 > . 10001:11001(1000) ack 1
// Limited transmit: on second dupack, send a new data segment.
+.01 < . 1:1(0) ack 1 win 320 <sack 1001:3001,nop,nop>
+0 > . 11001:12001(1000) ack 1
// It turned out to be reordering, not loss.
+.01 < . 1:1(0) ack 3001 win 320
+0 > P. 12001:14001(2000) ack 1
+.02 < . 1:1(0) ack 5001 win 320
+0 > P. 14001:15001(1000) ack 1
// Client gradually ACKs all data.
+.02 < . 1:1(0) ack 7001 win 320
+.02 < . 1:1(0) ack 9001 win 320
+.02 < . 1:1(0) ack 11001 win 320
+.02 < . 1:1(0) ack 13001 win 320
+.02 < . 1:1(0) ack 15001 win 320
// Clean up.
+.17 close(4) = 0
+0 > F. 15001:15001(0) ack 1
+.1 < F. 1:1(0) ack 15002 win 257
+0 > . 15002:15002(0) ack 2

40
tools/testing/selftests/net/packetdrill/tcp_nagle_https_client.pkt Normal file
View File

@ -0,0 +1,40 @@
// SPDX-License-Identifier: GPL-2.0
// This is a test inspired by an Android client app using SSL. This
// test verifies using TCP_NODELAY would save application latency
// (Perhaps even better with TCP_NAGLE).
//
`./defaults.sh
ethtool -K tun0 tso off gso off
./set_sysctls.py /proc/sys/net/ipv4/tcp_timestamps=0`
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 4
+0 fcntl(4, F_SETFL, O_RDWR|O_NONBLOCK) = 0
+0 setsockopt(4, SOL_TCP, TCP_NODELAY, [1], 4) = 0
+0 connect(4, ..., ...) = -1 EINPROGRESS (Operation now in progress)
+0 > S 0:0(0) <mss 1460,nop,nop,sackOK,nop,wscale 8>
+.1 < S. 0:0(0) ack 1 win 5792 <mss 974,nop,nop,sackOK,nop,wscale 7>
+0 > . 1:1(0) ack 1
// SSL handshake (resumed session)
+0 write(4, ..., 517) = 517
+0 > P. 1:518(517) ack 1
+.1 < . 1:1(0) ack 518 win 229
+0 < P. 1:144(143) ack 1 win 229
+0 > . 518:518(0) ack 144
+0 read(4, ..., 1000) = 143
// Application POST header (51B) and body (2002B)
+0 write(4, ..., 51) = 51
+0 > P. 518:569(51) ack 144
+.03 write(4, ..., 2002) = 2002
+0 > . 569:1543(974) ack 144
+0 > P. 1543:2517(974) ack 144
// Without disabling Nagle, this packet will not happen until the remote ACK.
+0 > P. 2517:2571(54) ack 144
+.1 < . 1:1(0) ack 2571 win 229
// Reset sysctls
`/tmp/sysctl_restore_${PPID}.sh`

66
tools/testing/selftests/net/packetdrill/tcp_nagle_sendmsg_msg_more.pkt Normal file
View File

@ -0,0 +1,66 @@
// SPDX-License-Identifier: GPL-2.0
// Test the MSG_MORE flag will correctly corks the tiny writes
`./defaults.sh`
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0 < S 0:0(0) win 32792 <mss 1000,nop,wscale 7>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,wscale 8>
+.01 < . 1:1(0) ack 1 win 257
+0 accept(3, ..., ...) = 4
// Disable Nagle by default on this socket.
+0 setsockopt(4, SOL_TCP, TCP_NODELAY, [1], 4) = 0
// Test the basic case: MSG_MORE overwrites TCP_NODELAY and enables Nagle.
+0 sendmsg(4, {msg_name(...)=...,
msg_iov(1)=[{..., 40}], msg_flags=0}, MSG_MORE) = 40
+.21~+.215 > P. 1:41(40) ack 1
+.01 < . 1:1(0) ack 41 win 257
// Test unsetting MSG_MORE releases the packet
+0 sendmsg(4, {msg_name(...)=...,
msg_iov(1)=[{..., 100}], msg_flags=0}, MSG_MORE) = 100
+.005 sendmsg(4, {msg_name(...)=...,
msg_iov(1)=[{..., 160}], msg_flags=0}, MSG_MORE) = 160
+.01 sendmsg(4, {msg_name(...)=...,
msg_iov(3)=[{..., 100}, {..., 200}, {..., 195}],
msg_flags=0}, MSG_MORE) = 495
+.008 sendmsg(4, {msg_name(...)=...,
msg_iov(1)=[{..., 5}], msg_flags=0}, 0) = 5
+0 > P. 41:801(760) ack 1
+.02 < . 1:1(0) ack 801 win 257
// Test >MSS write will unleash MSS packets but hold on the remaining data.
+.1 sendmsg(4, {msg_name(...)=...,
msg_iov(1)=[{..., 3100}], msg_flags=0}, MSG_MORE) = 3100
+0 > . 801:3801(3000) ack 1
+.003 sendmsg(4, {msg_name(...)=...,
msg_iov(1)=[{..., 50}], msg_flags=0}, MSG_MORE) = 50
+.01 < . 1:1(0) ack 2801 win 257
// Err... we relase the remaining right after the ACK? note that PUSH is reset
+0 > . 3801:3951(150) ack 1
// Test we'll hold on the subsequent writes when inflight (3801:3951) > 0
+.001 sendmsg(4, {msg_name(...)=...,
msg_iov(1)=[{..., 1}], msg_flags=0}, MSG_MORE) = 1
+.002 sendmsg(4, {msg_name(...)=...,
msg_iov(1)=[{..., 2}], msg_flags=0}, MSG_MORE) = 2
+.003 sendmsg(4, {msg_name(...)=...,
msg_iov(1)=[{..., 3}], msg_flags=0}, MSG_MORE) = 3
+.004 sendmsg(4, {msg_name(...)=...,
msg_iov(1)=[{..., 4}], msg_flags=0}, MSG_MORE) = 4
+.02 < . 1:1(0) ack 3951 win 257
+0 > . 3951:3961(10) ack 1
+.02 < . 1:1(0) ack 3961 win 257
// Test the case a MSG_MORE send followed by a write flushes the data
+0 sendmsg(4, {msg_name(...)=...,
msg_iov(1)=[{..., 20}], msg_flags=0}, MSG_MORE) = 20
+.05 write(4, ..., 20) = 20
+0 > P. 3961:4001(40) ack 1

43
tools/testing/selftests/net/packetdrill/tcp_nagle_sockopt_cork_nodelay.pkt Normal file
View File

@ -0,0 +1,43 @@
// SPDX-License-Identifier: GPL-2.0
// Test TCP_CORK and TCP_NODELAY sockopt behavior
`./defaults.sh`
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0 < S 0:0(0) win 32792 <mss 1000,nop,wscale 7>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,wscale 8>
+.01 < . 1:1(0) ack 1 win 257
+0 accept(3, ..., ...) = 4
// Set TCP_CORK sockopt to hold small packets
+0 setsockopt(4, SOL_TCP, TCP_CORK, [1], 4) = 0
+0 write(4, ..., 40) = 40
+.05 write(4, ..., 40) = 40
// Unset TCP_CORK should push pending bytes out
+.01 setsockopt(4, SOL_TCP, TCP_CORK, [0], 4) = 0
+0 > P. 1:81(80) ack 1
+.01 < . 1:1(0) ack 81 win 257
// Set TCP_CORK sockopt to hold small packets
+0 setsockopt(4, SOL_TCP, TCP_CORK, [1], 4) = 0
+0 write(4, ..., 40) = 40
+.05 write(4, ..., 40) = 40
// Set TCP_NODELAY sockopt should push pending bytes out
+0 setsockopt(4, SOL_TCP, TCP_NODELAY, [1], 4) = 0
+0 > P. 81:161(80) ack 1
+.01 < . 1:1(0) ack 161 win 257
// Set MSG_MORE to hold small packets
+0 send(4, ..., 40, MSG_MORE) = 40
+.05 send(4, ..., 40, MSG_MORE) = 40
// Set TCP_NODELAY sockopt should push pending bytes out
+.01 setsockopt(4, SOL_TCP, TCP_NODELAY, [1], 4) = 0
+0 > . 161:241(80) ack 1
+.01 < . 1:1(0) ack 241 win 257

37
tools/testing/selftests/net/packetdrill/tcp_sack_sack-route-refresh-ip-tos.pkt Normal file
View File

@ -0,0 +1,37 @@
// SPDX-License-Identifier: GPL-2.0
// Verify that setsockopt calls that force a route refresh do not
// cause problems matching SACKs with packets in the write queue.
// This variant tests IP_TOS.
`./defaults.sh`
// Establish a connection.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_IP, IP_MTU_DISCOVER, [IP_PMTUDISC_DONT], 1) = 0
+0...0.010 connect(3, ..., ...) = 0
+0 > S 0:0(0) <mss 1460,sackOK,TS val 100 ecr 0,nop,wscale 8>
+.01 < S. 0:0(0) ack 1 win 65535 <mss 1460,nop,wscale 2,nop,nop,sackOK>
+0 > . 1:1(0) ack 1
+.01 write(3, ..., 5840) = 5840
+0 > P. 1:5841(5840) ack 1
+.01 < . 1:1(0) ack 5841 win 65535
+.01 write(3, ..., 5840) = 5840
+0 > P. 5841:11681(5840) ack 1
+.01 < . 1:1(0) ack 11681 win 65535
+.01 write(3, ..., 14600) = 14600
+0 > P. 11681:26281(14600) ack 1
// Try the socket option that we know can force a route refresh.
+0 setsockopt(3, SOL_IP, IP_TOS, [4], 1) = 0
// Then revert to avoid routing/mangling/etc implications of that setting.
+0 setsockopt(3, SOL_IP, IP_TOS, [0], 1) = 0
// Verify that we do not retransmit the SACKed segments.
+.01 < . 1:1(0) ack 13141 win 65535 <sack 16061:17521 20441:26281,nop,nop>
+0 > . 13141:16061(2920) ack 1
+0 > P. 17521:20441(2920) ack 1
+.01 < . 1:1(0) ack 26281 win 65535

64
tools/testing/selftests/net/packetdrill/tcp_sack_sack-shift-sacked-2-6-8-3-9-nofack.pkt Normal file
View File

@ -0,0 +1,64 @@
// SPDX-License-Identifier: GPL-2.0
// Test shifting of newly-SACKed ranges onto the previous already-SACKed skb.
// This variant tests non-FACK SACK with SACKs coming in the order
// 2 6 8 3 9, to test what happens when we get a new SACKed range
// (for packet 3) that is on the right of an existing SACKed range
// (for packet 2).
`./defaults.sh`
// Establish a connection and send 10 MSS.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0 < S 0:0(0) win 32792 <mss 1000,sackOK,nop,nop,nop,wscale 7>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,nop,sackOK,nop,wscale 8>
+.1 < . 1:1(0) ack 1 win 1024
+0 accept(3, ..., ...) = 4
+0 write(4, ..., 10000) = 10000
+0 > P. 1:10001(10000) ack 1
+.1 < . 1:1(0) ack 1 win 257 <sack 2001:3001,nop,nop>
+.001 < . 1:1(0) ack 1 win 257 <sack 2001:3001 6001:7001,nop,nop>
+.001 < . 1:1(0) ack 1 win 257 <sack 2001:3001 6001:7001 8001:9001,nop,nop>
// 3 SACKed packets, so we enter Fast Recovery.
+0 > . 1:1001(1000) ack 1
+0 %{ assert tcpi_ca_state == TCP_CA_Recovery, tcpi_ca_state }%
+0 %{ assert tcpi_lost == 6, tcpi_lost }%
// SACK for 3001:4001.
// This SACK for an adjacent range causes the sender to
// shift the newly-SACKed range onto the previous skb.
+.007 < . 1:1(0) ack 1 win 257 <sack 2001:4001 6001:7001 8001:9001,nop,nop>
+0 > . 1001:2001(1000) ack 1
+0 %{ assert tcpi_lost == 5, tcpi_lost }%
+0 %{ assert tcpi_reordering == 6, tcpi_reordering }% // 8001:9001 -> 3001:4001 is 6
// SACK for 9001:10001.
+.01 < . 1:1(0) ack 1 win 257 <sack 2001:4001 6001:7001 8001:10001,nop,nop>
+0 %{ assert tcpi_lost == 5, tcpi_lost }%
// ACK for 1:1001 as packets from t=0.303 arrive.
+.083 < . 1:1(0) ack 1001 win 257 <sack 2001:4001 6001:7001 8001:10001,nop,nop>
+0 %{ assert tcpi_lost == 4,tcpi_lost }%
// ACK for 1:4001 as packets from t=0.310 arrive.
+.017 < . 1:1(0) ack 4001 win 257 <sack 6001:7001 8001:10001,nop,nop>
+0 %{ assert tcpi_lost == 3,tcpi_lost }%
// ACK for 1:7001 as packets from t=0.320 arrive.
+.01 < . 1:1(0) ack 7001 win 257 <sack 8001:10001,nop,nop>
// ACK for all data as packets from t=0.403 arrive.
+.1 < . 1:1(0) ack 10001 win 257
+0 %{
assert tcpi_ca_state == TCP_CA_Open, tcpi_ca_state
assert tcpi_unacked == 0, tcpi_unacked
assert tcpi_sacked == 0, tcpi_sacked
assert tcpi_lost == 0, tcpi_lost
assert tcpi_retrans == 0, tcpi_retrans
}%

66
tools/testing/selftests/net/packetdrill/tcp_sack_sack-shift-sacked-7-3-4-8-9-fack.pkt Normal file
View File

@ -0,0 +1,66 @@
// SPDX-License-Identifier: GPL-2.0
// Test shifting of newly-SACKed ranges onto the previous already-SACKed skb.
// This variant tests the case where we mark packets 0-4 lost, then
// get a SACK for 3, and then a SACK for 4.
`./defaults.sh`
// Establish a connection and send 10 MSS.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0 < S 0:0(0) win 32792 <mss 1000,sackOK,nop,nop,nop,wscale 7>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,nop,sackOK,nop,wscale 8>
+.1 < . 1:1(0) ack 1 win 1024
+0 accept(3, ..., ...) = 4
+0 write(4, ..., 10000) = 10000
+0 > P. 1:10001(10000) ack 1
// SACK for 7001:8001. Using RACK we delay the fast retransmit.
+.1 < . 1:1(0) ack 1 win 257 <sack 7001:8001,nop,nop>
// RACK reordering timer
+.027 > . 1:1001(1000) ack 1
+0 %{
assert tcpi_ca_state == TCP_CA_Recovery, tcpi_ca_state
assert tcpi_lost == 7, tcpi_lost # RACK thinks 1:7001 are lost
assert tcpi_reordering == 3, tcpi_reordering
}%
// SACK for 3001:4001.
+.002 < . 1:1(0) ack 1 win 257 <sack 3001:4001 7001:8001,nop,nop>
+0 > . 1001:2001(1000) ack 1
+0 %{
assert tcpi_lost == 6, tcpi_lost # since 3001:4001 is no longer lost
assert tcpi_reordering == 5, tcpi_reordering # 7001:8001 -> 3001:4001
}%
// SACK for 4001:5001.
// This SACK for an adjacent range causes the sender to
// shift the newly-SACKed range onto the previous skb.
// It uses the RFC3517 algorithm to mark 1:3001 lost
// because >=3 higher-sequence packets are SACKed.
+.002 < . 1:1(0) ack 1 win 257 <sack 3001:5001 7001:8001,nop,nop>
+0 > . 2001:3001(1000) ack 1
+0 %{
assert tcpi_lost == 5,tcpi_lost # SACK/RFC3517 thinks 1:3001 are lost
}%
// SACK for 8001:9001.
+.002 < . 1:1(0) ack 1 win 257 <sack 3001:5001 7001:9001,nop,nop>
// SACK for 9001:10001.
+.002 < . 1:1(0) ack 1 win 257 <sack 3001:5001 7001:10001,nop,nop>
+0 > . 5001:6001(1000) ack 1
// To simplify clean-up, say we get an ACK for all data.
+.1 < . 1:1(0) ack 10001 win 257
+0 %{
assert tcpi_ca_state == TCP_CA_Open, tcpi_ca_state
assert tcpi_unacked == 0, tcpi_unacked
assert tcpi_sacked == 0, tcpi_sacked
assert tcpi_lost == 0, tcpi_lost
assert tcpi_retrans == 0, tcpi_retrans
}%

62
tools/testing/selftests/net/packetdrill/tcp_sack_sack-shift-sacked-7-5-6-8-9-fack.pkt Normal file
View File

@ -0,0 +1,62 @@
// SPDX-License-Identifier: GPL-2.0
// Test shifting of newly-SACKed ranges onto the previous already-SACKed skb.
// This variant tests the case where we mark packets 0-4 lost, then
// get a SACK for 5, and then a SACK for 6.
`./defaults.sh`
// Establish a connection and send 10 MSS.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0 < S 0:0(0) win 32792 <mss 1000,sackOK,nop,nop,nop,wscale 7>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,nop,sackOK,nop,wscale 8>
+.1 < . 1:1(0) ack 1 win 1024
+0 accept(3, ..., ...) = 4
+0 write(4, ..., 10000) = 10000
+0 > P. 1:10001(10000) ack 1
// SACK for 7001:8001. Using RACK we delay a fast retransmit.
+.1 < . 1:1(0) ack 1 win 257 <sack 7001:8001,nop,nop>
+.027 > . 1:1001(1000) ack 1
+0 %{
assert tcpi_ca_state == TCP_CA_Recovery, tcpi_ca_state
assert tcpi_lost == 7,tcpi_lost # RACK thinks 1:7001 are lost
assert tcpi_reordering == 3, tcpi_reordering
}%
// SACK for 5001:6001.
+0 < . 1:1(0) ack 1 win 257 <sack 5001:6001 7001:8001,nop,nop>
+0 > . 1001:2001(1000) ack 1
+0 %{
assert tcpi_lost == 6, tcpi_lost
assert tcpi_reordering == 3, tcpi_reordering # 7001:8001 -> 5001:6001 is 3
}%
// SACK for 6001:7001.
// This SACK for an adjacent range causes the sender to
// shift the newly-SACKed range onto the previous skb.
+0 < . 1:1(0) ack 1 win 257 <sack 5001:8001,nop,nop>
+0 > . 2001:3001(1000) ack 1
+0 %{ assert tcpi_lost == 5, tcpi_lost }%
// SACK for 8001:9001.
+0 < . 1:1(0) ack 1 win 257 <sack 5001:9001,nop,nop>
+0 > . 3001:4001(1000) ack 1
// SACK for 9001:10001.
+0 < . 1:1(0) ack 1 win 257 <sack 5001:10001,nop,nop>
+0 > . 4001:5001(1000) ack 1
// To simplify clean-up, say we get an ACK for all data.
+.1 < . 1:1(0) ack 10001 win 257
+0 %{
assert tcpi_ca_state == TCP_CA_Open, tcpi_ca_state
assert tcpi_unacked == 0, tcpi_unacked
assert tcpi_sacked == 0, tcpi_sacked
assert tcpi_lost == 0, tcpi_lost
assert tcpi_retrans == 0, tcpi_retrans
}%

26
tools/testing/selftests/net/packetdrill/tcp_sendfile_sendfile-simple.pkt Normal file
View File

@ -0,0 +1,26 @@
// SPDX-License-Identifier: GPL-2.0
// Simplest possible test of open() and then sendfile().
// We write some zeroes into a file (since packetdrill expects payloads
// to be all zeroes) and then open() the file, then use sendfile()
// and verify that the correct number of zeroes goes out.
`./defaults.sh
/bin/rm -f /tmp/testfile
/bin/dd bs=1 count=5 if=/dev/zero of=/tmp/testfile status=none
`
// Initialize connection
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0 < S 0:0(0) win 32792 <mss 1000,sackOK,nop,nop,nop,wscale 10>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,nop,sackOK,nop,wscale 8>
+0 < . 1:1(0) ack 1 win 514
+0 accept(3, ..., ...) = 4
+0 open("/tmp/testfile", O_RDONLY) = 5
+0 sendfile(4, 5, [0], 5) = 5
+0 > P. 1:6(5) ack 1

20
tools/testing/selftests/net/packetdrill/tcp_splice_tcp_splice_loop_test.pkt Normal file
View File

@ -0,0 +1,20 @@
// SPDX-License-Identifier: GPL-2.0
`./defaults.sh`
// Initialize a server socket
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 setsockopt(3, SOL_IP, IP_FREEBIND, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
// Connection should get accepted
+0 < S 0:0(0) win 32972 <mss 1460,nop,wscale 7>
+0 > S. 0:0(0) ack 1 <...>
+0 < . 1:1(0) ack 1 win 257
+0 accept(3, ..., ...) = 4
+0 pipe([5, 6]) = 0
+0 < U. 1:101(100) ack 1 win 257 urg 100
+0 splice(4, NULL, 6, NULL, 99, 0) = 99
+0 splice(4, NULL, 6, NULL, 1, 0) = 0

42
tools/testing/selftests/net/packetdrill/tcp_syscall_bad_arg_fastopen-invalid-buf-ptr.pkt Normal file
View File

@ -0,0 +1,42 @@
// SPDX-License-Identifier: GPL-2.0
// Test TCP fastopen behavior with NULL as buffer pointer, but a non-zero
// buffer length.
`./defaults.sh
./set_sysctls.py /proc/sys/net/ipv4/tcp_timestamps=0`
// Cache warmup: send a Fast Open cookie request
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 fcntl(3, F_SETFL, O_RDWR|O_NONBLOCK) = 0
+0 setsockopt(3, SOL_TCP, TCP_FASTOPEN_CONNECT, [1], 4) = 0
+0 connect(3, ..., ...) = -1 EINPROGRESS (Operation is now in progress)
+0 > S 0:0(0) <mss 1460,nop,nop,sackOK,nop,wscale 8,FO,nop,nop>
+0 < S. 123:123(0) ack 1 win 14600 <mss 1460,nop,nop,sackOK,nop,wscale 6,FO abcd1234,nop,nop>
+0 > . 1:1(0) ack 1
+0 close(3) = 0
+0 > F. 1:1(0) ack 1
+0 < F. 1:1(0) ack 2 win 92
+0 > . 2:2(0) ack 2
// Test with MSG_FASTOPEN without TCP_FASTOPEN_CONNECT.
+0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 4
+0 fcntl(4, F_SETFL, O_RDWR|O_NONBLOCK) = 0
+0 sendto(4, NULL, 1, MSG_FASTOPEN, ..., ...) = -1
+0 close(4) = 0
// Test with TCP_FASTOPEN_CONNECT without MSG_FASTOPEN.
+0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 5
+0 fcntl(5, F_SETFL, O_RDWR|O_NONBLOCK) = 0
+0 setsockopt(5, SOL_TCP, TCP_FASTOPEN_CONNECT, [1], 4) = 0
+0 connect(5, ..., ...) = 0
+0 sendto(5, NULL, 1, 0, ..., ...) = -1
+0 close(5) = 0
// Test with both TCP_FASTOPEN_CONNECT and MSG_FASTOPEN.
+0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 6
+0 fcntl(6, F_SETFL, O_RDWR|O_NONBLOCK) = 0
+0 setsockopt(6, SOL_TCP, TCP_FASTOPEN_CONNECT, [1], 4) = 0
+0 connect(6, ..., ...) = 0
+0 sendto(6, NULL, 1, MSG_FASTOPEN, ..., ...) = -1
+0 close(6) = 0
`/tmp/sysctl_restore_${PPID}.sh`

30
tools/testing/selftests/net/packetdrill/tcp_syscall_bad_arg_sendmsg-empty-iov.pkt Normal file
View File

@ -0,0 +1,30 @@
// SPDX-License-Identifier: GPL-2.0
// Test that we correctly skip zero-length IOVs.
`./defaults.sh`
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_ZEROCOPY, [1], 4) = 0
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0 < S 0:0(0) win 32792 <mss 1000,nop,wscale 7>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,wscale 8>
+.01 < . 1:1(0) ack 1 win 257
+0 accept(3, ..., ...) = 4
+0 setsockopt(4, SOL_TCP, TCP_NODELAY, [1], 4) = 0
+0 sendmsg(4, {msg_name(...)=...,
msg_iov(4)=[{..., 0}, {..., 40}, {..., 0}, {..., 20}],
msg_flags=0}, 0) = 60
+0 > P. 1:61(60) ack 1
+.01 < . 1:1(0) ack 61 win 257
+0 sendmsg(4, {msg_name(...)=...,
msg_iov(4)=[{..., 0}, {..., 0}, {..., 0}, {..., 0}],
msg_flags=0}, MSG_ZEROCOPY) = 0
+0 sendmsg(4, {msg_name(...)=...,
msg_iov(4)=[{..., 0}, {..., 10}, {..., 0}, {..., 50}],
msg_flags=0}, MSG_ZEROCOPY) = 60
+0 > P. 61:121(60) ack 1
+.01 < . 1:1(0) ack 121 win 257

25
tools/testing/selftests/net/packetdrill/tcp_syscall_bad_arg_syscall-invalid-buf-ptr.pkt Normal file
View File

@ -0,0 +1,25 @@
// SPDX-License-Identifier: GPL-2.0
// Test kernel behavior with NULL as buffer pointer
`./defaults.sh`
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 fcntl(3, F_SETFL, O_RDWR|O_NONBLOCK) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0 < S 0:0(0) win 32792 <mss 1000,sackOK,nop,nop,nop,wscale 10>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,nop,sackOK,nop,wscale 8>
+.2 < . 1:1(0) ack 1 win 514
+0 accept(3, ..., ...) = 4
+0 write(4, NULL, 1000) = -1 EFAULT (Bad address)
+0 send(4, NULL, 1000, 0) = -1 EFAULT (Bad address)
+0 sendto(4, NULL, 1000, 0, ..., ...) = -1 EFAULT (Bad address)
+0 < . 1:1001(1000) ack 1 win 200
+0 read(4, NULL, 1000) = -1 EFAULT (Bad address)
+0 recv(4, NULL, 1000, 0) = -1 EFAULT (Bad address)
+0 recvfrom(4, NULL, 1000, 0, ..., ...) = -1 EFAULT (Bad address)

20
tools/testing/selftests/net/packetdrill/tcp_tcp_info_tcp-info-last_data_recv.pkt Normal file
View File

@ -0,0 +1,20 @@
// SPDX-License-Identifier: GPL-2.0
// Test tcpi_last_data_recv for active session
`./defaults.sh`
// Create a socket and set it to non-blocking.
+0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 fcntl(3, F_GETFL) = 0x2 (flags O_RDWR)
+0 fcntl(3, F_SETFL, O_RDWR|O_NONBLOCK) = 0
+0 connect(3, ..., ...) = -1 EINPROGRESS (Operation now in progress)
+0 > S 0:0(0) <mss 1460,sackOK,TS val 100 ecr 0,nop,wscale 8>
+.030 < S. 0:0(0) ack 1 win 10000 <mss 1000,sackOK,nop,nop,nop,wscale 8>
+0 > . 1:1(0) ack 1
+1 %{ assert 990 <= tcpi_last_data_recv <= 1010, tcpi_last_data_recv }%
+0 < . 1:1001(1000) ack 1 win 300
+0 > . 1:1(0) ack 1001
+0 %{ assert tcpi_last_data_recv <= 10, tcpi_last_data_recv }%

54
tools/testing/selftests/net/packetdrill/tcp_tcp_info_tcp-info-rwnd-limited.pkt Normal file
View File

@ -0,0 +1,54 @@
// SPDX-License-Identifier: GPL-2.0
// Test rwnd limited time in tcp_info for client side.
`./defaults.sh`
// Create a socket and set it to non-blocking.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 fcntl(3, F_GETFL) = 0x2 (flags O_RDWR)
+0 fcntl(3, F_SETFL, O_RDWR|O_NONBLOCK) = 0
+0 connect(3, ..., ...) = -1 EINPROGRESS (Operation now in progress)
+0 > S 0:0(0) <mss 1460,sackOK,TS val 100 ecr 0,nop,wscale 8>
// Server advertises 0 receive window.
+.01 < S. 0:0(0) ack 1 win 0 <mss 1000,nop,nop,sackOK>
+0 > . 1:1(0) ack 1
+0 getsockopt(3, SOL_SOCKET, SO_ERROR, [0], [4]) = 0
+0 fcntl(3, F_SETFL, O_RDWR) = 0 // set back to blocking
// Make sure that initial rwnd limited time is 0.
+0 %{ assert tcpi_rwnd_limited == 0, tcpi_rwnd_limited }%
// Receive window limited time starts here.
+0 write(3, ..., 1000) = 1000
// Check that rwnd limited time in tcp_info is around 0.1s.
+.1 %{ assert 98000 <= tcpi_rwnd_limited <= 110000, tcpi_rwnd_limited }%
// Server opens the receive window.
+.1 < . 1:1(0) ack 1 win 2000
// Check that rwnd limited time in tcp_info is around 0.2s.
+0 %{ assert 198000 <= tcpi_rwnd_limited <= 210000, tcpi_rwnd_limited }%
+0 > P. 1:1001(1000) ack 1
// Server advertises a very small receive window.
+.03 < . 1:1(0) ack 1001 win 10
// Receive window limited time starts again.
+0 write(3, ..., 1000) = 1000
// Server opens the receive window again.
+.1 < . 1:1(0) ack 1001 win 2000
// Check that rwnd limited time in tcp_info is around 0.3s
// and busy time is 0.3 + 0.03 (server opened small window temporarily).
+0 %{ assert 298000 <= tcpi_rwnd_limited <= 310000, tcpi_rwnd_limited;\
assert 328000 <= tcpi_busy_time <= 340000, tcpi_busy_time;\
}%
+0 > P. 1001:2001(1000) ack 1
+.02 < . 1:1(0) ack 2001 win 2000
+0 %{ assert 348000 <= tcpi_busy_time <= 360000, tcpi_busy_time }%

38
tools/testing/selftests/net/packetdrill/tcp_tcp_info_tcp-info-sndbuf-limited.pkt Normal file
View File

@ -0,0 +1,38 @@
// SPDX-License-Identifier: GPL-2.0
// Test send-buffer-limited time in tcp_info for client side.
`./defaults.sh`
// Create a socket and set it to non-blocking.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 fcntl(3, F_GETFL) = 0x2 (flags O_RDWR)
+0 fcntl(3, F_SETFL, O_RDWR|O_NONBLOCK) = 0
+0 connect(3, ..., ...) = -1 EINPROGRESS (Operation now in progress)
+0 > S 0:0(0) <mss 1460,sackOK,TS val 100 ecr 0,nop,wscale 8>
+.01 < S. 0:0(0) ack 1 win 10000 <mss 1000,sackOK,nop,nop,nop,wscale 8>
+0 > . 1:1(0) ack 1
+0 getsockopt(3, SOL_SOCKET, SO_ERROR, [0], [4]) = 0
+0 fcntl(3, F_SETFL, O_RDWR) = 0 // set back to blocking
+0 setsockopt(3, SOL_SOCKET, SO_SNDBUF, [10000], 4) = 0
+0 getsockopt(3, SOL_SOCKET, SO_SNDBUF, [20000], [4]) = 0
+.09...0.14 write(3, ..., 150000) = 150000
+.01 < . 1:1(0) ack 10001 win 10000
+.01 < . 1:1(0) ack 30001 win 10000
// cwnd goes from 40(60KB) to 80(120KB), and that we hit the tiny sndbuf limit 10KB
+.01 < . 1:1(0) ack 70001 win 10000
+.02 < . 1:1(0) ack 95001 win 10000
+0 %{ assert 19000 <= tcpi_sndbuf_limited <= 21000, tcpi_sndbuf_limited; \
assert 49000 <= tcpi_busy_time <= 52000, tcpi_busy_time; \
assert 0 == tcpi_rwnd_limited, tcpi_rwnd_limited }%
// This ack frees up enough buffer so we are no longer
// buffer limited (socket flag SOCK_NOSPACE is cleared)
+.02 < . 1:1(0) ack 150001 win 10000
+0 %{ assert 19000 <= tcpi_sndbuf_limited <= 21000, tcpi_sndbuf_limited;\
assert 69000 <= tcpi_busy_time <= 73000, tcpi_busy_time;\
assert 0 == tcpi_rwnd_limited, tcpi_rwnd_limited }%

92
tools/testing/selftests/net/packetdrill/tcp_timestamping_client-only-last-byte.pkt Normal file
View File

@ -0,0 +1,92 @@
// SPDX-License-Identifier: GPL-2.0
// Test that tx timestamping sends timestamps only for
// the last byte of each sendmsg.
`./defaults.sh
`
// Create a socket and set it to non-blocking.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 fcntl(3, F_GETFL) = 0x2 (flags O_RDWR)
+0 fcntl(3, F_SETFL, O_RDWR|O_NONBLOCK) = 0
// Establish connection and verify that there was no error.
+0 connect(3, ..., ...) = -1 EINPROGRESS (Operation now in progress)
+0 > S 0:0(0) <mss 1460,sackOK,TS val 100 ecr 0,nop,wscale 8>
+.01 < S. 0:0(0) ack 1 win 20000 <mss 1000,nop,nop,sackOK>
+0 > . 1:1(0) ack 1
+0 getsockopt(3, SOL_SOCKET, SO_ERROR, [0], [4]) = 0
+0 fcntl(3, F_SETFL, O_RDWR) = 0 // set back to blocking
+0 setsockopt(3, SOL_SOCKET, SO_TIMESTAMPING,
[SOF_TIMESTAMPING_TX_SCHED | SOF_TIMESTAMPING_TX_SOFTWARE |
SOF_TIMESTAMPING_TX_ACK | SOF_TIMESTAMPING_SOFTWARE |
SOF_TIMESTAMPING_OPT_ID], 4) = 0
+0 write(3, ..., 11000) = 11000
+0 > P. 1:10001(10000) ack 1
+.01 < . 1:1(0) ack 10001 win 4000
+0 > P. 10001:11001(1000) ack 1
+.01 < . 1:1(0) ack 11001 win 4000
// Make sure that internal TCP timestamps are not overwritten and we have sane
// RTT measurement.
+0 %{
assert 5000 <= tcpi_rtt <= 20000, 'srtt=%d us' % tcpi_rtt
}%
// SCM_TSTAMP_SCHED for the last byte should be received almost immediately
// once 10001 is acked at t=20ms.
// setsockopt(..., [SOF_TIMESTAMPING_SOFTWARE | SOF_TIMESTAMPING_OPT_ID], ...)
// is called after when SYN is acked. So, we expect the last byte of the first
// chunk to have a timestamp key of 10999 (i.e., 11000 - 1).
+0 recvmsg(3, {msg_name(...)=...,
msg_iov(1)=[{...,0}],
msg_flags=MSG_ERRQUEUE|MSG_TRUNC,
msg_control=[
{cmsg_level=SOL_SOCKET,
cmsg_type=SCM_TIMESTAMPING,
cmsg_data={scm_sec=0,scm_nsec=20000000}},
{cmsg_level=CMSG_LEVEL_IP,
cmsg_type=CMSG_TYPE_RECVERR,
cmsg_data={ee_errno=ENOMSG,
ee_origin=SO_EE_ORIGIN_TIMESTAMPING,
ee_type=0,
ee_code=0,
ee_info=SCM_TSTAMP_SCHED,
ee_data=10999}}
]}, MSG_ERRQUEUE) = 0
// SCM_TSTAMP_SND for the last byte should be received almost immediately
// once 10001 is acked at t=20ms.
+0 recvmsg(3, {msg_name(...)=...,
msg_iov(1)=[{...,0}],
msg_flags=MSG_ERRQUEUE|MSG_TRUNC,
msg_control=[
{cmsg_level=SOL_SOCKET,
cmsg_type=SCM_TIMESTAMPING,
cmsg_data={scm_sec=0,scm_nsec=20000000}},
{cmsg_level=CMSG_LEVEL_IP,
cmsg_type=CMSG_TYPE_RECVERR,
cmsg_data={ee_errno=ENOMSG,
ee_origin=SO_EE_ORIGIN_TIMESTAMPING,
ee_type=0,
ee_code=0,
ee_info=SCM_TSTAMP_SND,
ee_data=10999}}
]}, MSG_ERRQUEUE) = 0
// SCM_TSTAMP_ACK for the last byte should be received at t=30ms.
+0 recvmsg(3, {msg_name(...)=...,
msg_iov(1)=[{...,0}],
msg_flags=MSG_ERRQUEUE|MSG_TRUNC,
msg_control=[
{cmsg_level=SOL_SOCKET,
cmsg_type=SCM_TIMESTAMPING,
cmsg_data={scm_sec=0,scm_nsec=30000000}},
{cmsg_level=CMSG_LEVEL_IP,
cmsg_type=CMSG_TYPE_RECVERR,
cmsg_data={ee_errno=ENOMSG,
ee_origin=SO_EE_ORIGIN_TIMESTAMPING,
ee_type=0,
ee_code=0,
ee_info=SCM_TSTAMP_ACK,
ee_data=10999}}
]}, MSG_ERRQUEUE) = 0

91
tools/testing/selftests/net/packetdrill/tcp_timestamping_partial.pkt Normal file
View File

@ -0,0 +1,91 @@
// SPDX-License-Identifier: GPL-2.0
// Test tx timestamping for partial writes (IPv4).
`./defaults.sh
`
// Create a socket and set it to non-blocking.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 fcntl(3, F_GETFL) = 0x2 (flags O_RDWR)
+0 fcntl(3, F_SETFL, O_RDWR|O_NONBLOCK) = 0
// Establish connection and verify that there was no error.
+0 connect(3, ..., ...) = -1 EINPROGRESS (Operation now in progress)
+0 > S 0:0(0) <mss 1460,sackOK,TS val 100 ecr 0,nop,wscale 8>
+.01 < S. 0:0(0) ack 1 win 2000 <mss 1000,sackOK,TS val 700 ecr 100,nop,wscale 7>
+0 > . 1:1(0) ack 1 <nop,nop,TS val 200 ecr 700>
+0 getsockopt(3, SOL_SOCKET, SO_ERROR, [0], [4]) = 0
+0 setsockopt(3, SOL_SOCKET, SO_SNDBUF, [1000], 4) = 0
+0 setsockopt(3, SOL_SOCKET, SO_TIMESTAMPING,
[SOF_TIMESTAMPING_TX_SCHED | SOF_TIMESTAMPING_TX_SOFTWARE |
SOF_TIMESTAMPING_TX_ACK | SOF_TIMESTAMPING_SOFTWARE |
SOF_TIMESTAMPING_OPT_ID], 4) = 0
// We have a partial write.
+0 write(3, ..., 10000) = 2964
+0 > . 1:989(988) ack 1 <nop,nop,TS val 110 ecr 700>
+0 > P. 989:1977(988) ack 1 <nop,nop,TS val 110 ecr 700>
+.01 < . 1:1(0) ack 1977 win 92 <nop,nop,TS val 800 ecr 200>
+0 > P. 1977:2965(988) ack 1 <nop,nop,TS val 114 ecr 800>
+.01 < . 1:1(0) ack 2965 win 92 <nop,nop,TS val 800 ecr 200>
// Make sure that internal TCP timestamps are not overwritten and we have sane
// RTT measurement.
+0 %{
assert 5000 <= tcpi_rtt <= 20000, 'srtt=%d us' % tcpi_rtt
}%
// SCM_TSTAMP_SCHED for the first chunk should be received almost immediately
// after the first ack at t=20ms.
+0 recvmsg(3, {msg_name(...)=...,
msg_iov(1)=[{...,0}],
msg_flags=MSG_ERRQUEUE|MSG_TRUNC,
msg_control=[
{cmsg_level=SOL_SOCKET,
cmsg_type=SCM_TIMESTAMPING,
cmsg_data={scm_sec=0,scm_nsec=20000000}},
{cmsg_level=CMSG_LEVEL_IP,
cmsg_type=CMSG_TYPE_RECVERR,
cmsg_data={ee_errno=ENOMSG,
ee_origin=SO_EE_ORIGIN_TIMESTAMPING,
ee_type=0,
ee_code=0,
ee_info=SCM_TSTAMP_SCHED,
ee_data=2963}}
]}, MSG_ERRQUEUE) = 0
// SCM_TSTAMP_SND for the first chunk should be received almost immediately
// after the first ack at t=20ms.
+0 recvmsg(3, {msg_name(...)=...,
msg_iov(1)=[{...,0}],
msg_flags=MSG_ERRQUEUE|MSG_TRUNC,
msg_control=[
{cmsg_level=SOL_SOCKET,
cmsg_type=SCM_TIMESTAMPING,
cmsg_data={scm_sec=0,scm_nsec=20000000}},
{cmsg_level=CMSG_LEVEL_IP,
cmsg_type=CMSG_TYPE_RECVERR,
cmsg_data={ee_errno=ENOMSG,
ee_origin=SO_EE_ORIGIN_TIMESTAMPING,
ee_type=0,
ee_code=0,
ee_info=SCM_TSTAMP_SND,
ee_data=2963}}
]}, MSG_ERRQUEUE) = 0
// SCM_TSTAMP_ACK for the first chunk should be received after the last ack at
// t=30ms.
+0 recvmsg(3, {msg_name(...)=...,
msg_iov(1)=[{...,0}],
msg_flags=MSG_ERRQUEUE|MSG_TRUNC,
msg_control=[
{cmsg_level=SOL_SOCKET,
cmsg_type=SCM_TIMESTAMPING,
cmsg_data={scm_sec=0,scm_nsec=30000000}},
{cmsg_level=CMSG_LEVEL_IP,
cmsg_type=CMSG_TYPE_RECVERR,
cmsg_data={ee_errno=ENOMSG,
ee_origin=SO_EE_ORIGIN_TIMESTAMPING,
ee_type=0,
ee_code=0,
ee_info=SCM_TSTAMP_ACK,
ee_data=2963}}
]}, MSG_ERRQUEUE) = 0

145
tools/testing/selftests/net/packetdrill/tcp_timestamping_server.pkt Normal file
View File

@ -0,0 +1,145 @@
// SPDX-License-Identifier: GPL-2.0
// Test tx timestamping for server-side (IPv4).
`./defaults.sh
`
// Initialize connection
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0 < S 0:0(0) win 32792 <mss 1000,sackOK,nop,nop,nop,wscale 10>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,nop,sackOK,nop,wscale 8>
+.01 < . 1:1(0) ack 1 win 514
+0 accept(3, ..., ...) = 4
+0 setsockopt(4, SOL_SOCKET, SO_TIMESTAMPING,
[SOF_TIMESTAMPING_TX_SCHED | SOF_TIMESTAMPING_TX_SOFTWARE |
SOF_TIMESTAMPING_TX_ACK | SOF_TIMESTAMPING_SOFTWARE |
SOF_TIMESTAMPING_OPT_ID], 4) = 0
// Write two 2KB chunks.
// setsockopt(..., [SOF_TIMESTAMPING_SOFTWARE | SOF_TIMESTAMPING_OPT_ID], ...)
// is called after when SYN is acked. So, we expect the last byte of the first
// and the second chunks to have timestamp keys of 1999 (i.e., 2000 - 1) and
// 3999 (i.e., 4000 - 1) respectively.
+0 write(4, ..., 2000) = 2000
+0 write(4, ..., 2000) = 2000
+0 > P. 1:2001(2000) ack 1
+0 > P. 2001:4001(2000) ack 1
+.01 < . 1:1(0) ack 2001 win 514
+.01 < . 1:1(0) ack 4001 win 514
// Make sure that internal TCP timestamps are not overwritten and we have sane
// RTT measurement.
+0 %{
assert 5000 <= tcpi_rtt <= 20000, 'srtt=%d us' % tcpi_rtt
}%
// SCM_TSTAMP_SCHED for the first chunk should be received almost immediately
// after write at t=10ms.
+0 recvmsg(4, {msg_name(...)=...,
msg_iov(1)=[{...,0}],
msg_flags=MSG_ERRQUEUE|MSG_TRUNC,
msg_control=[
{cmsg_level=SOL_SOCKET,
cmsg_type=SCM_TIMESTAMPING,
cmsg_data={scm_sec=0,scm_nsec=10000000}},
{cmsg_level=CMSG_LEVEL_IP,
cmsg_type=CMSG_TYPE_RECVERR,
cmsg_data={ee_errno=ENOMSG,
ee_origin=SO_EE_ORIGIN_TIMESTAMPING,
ee_type=0,
ee_code=0,
ee_info=SCM_TSTAMP_SCHED,
ee_data=1999}}
]}, MSG_ERRQUEUE) = 0
// SCM_TSTAMP_SND for the first chunk should be received almost immediately
// after write at t=10ms.
+0 recvmsg(4, {msg_name(...)=...,
msg_iov(1)=[{...,0}],
msg_flags=MSG_ERRQUEUE|MSG_TRUNC,
msg_control=[
{cmsg_level=SOL_SOCKET,
cmsg_type=SCM_TIMESTAMPING,
cmsg_data={scm_sec=0,scm_nsec=10000000}},
{cmsg_level=CMSG_LEVEL_IP,
cmsg_type=CMSG_TYPE_RECVERR,
cmsg_data={ee_errno=ENOMSG,
ee_origin=SO_EE_ORIGIN_TIMESTAMPING,
ee_type=0,
ee_code=0,
ee_info=SCM_TSTAMP_SND,
ee_data=1999}}
]}, MSG_ERRQUEUE) = 0
// SCM_TSTAMP_SCHED for the second chunk should be received almost immediately
// after that at t=10ms.
+0 recvmsg(4, {msg_name(...)=...,
msg_iov(1)=[{...,0}],
msg_flags=MSG_ERRQUEUE|MSG_TRUNC,
msg_control=[
{cmsg_level=SOL_SOCKET,
cmsg_type=SCM_TIMESTAMPING,
cmsg_data={scm_sec=0,scm_nsec=10000000}},
{cmsg_level=CMSG_LEVEL_IP,
cmsg_type=CMSG_TYPE_RECVERR,
cmsg_data={ee_errno=ENOMSG,
ee_origin=SO_EE_ORIGIN_TIMESTAMPING,
ee_type=0,
ee_code=0,
ee_info=SCM_TSTAMP_SCHED,
ee_data=3999}}
]}, MSG_ERRQUEUE) = 0
// SCM_TSTAMP_SND for the second chunk should be received almost immediately
// after that at t=10ms.
+0 recvmsg(4, {msg_name(...)=...,
msg_iov(1)=[{...,0}],
msg_flags=MSG_ERRQUEUE|MSG_TRUNC,
msg_control=[
{cmsg_level=SOL_SOCKET,
cmsg_type=SCM_TIMESTAMPING,
cmsg_data={scm_sec=0,scm_nsec=10000000}},
{cmsg_level=CMSG_LEVEL_IP,
cmsg_type=CMSG_TYPE_RECVERR,
cmsg_data={ee_errno=ENOMSG,
ee_origin=SO_EE_ORIGIN_TIMESTAMPING,
ee_type=0,
ee_code=0,
ee_info=SCM_TSTAMP_SND,
ee_data=3999}}
]}, MSG_ERRQUEUE) = 0
// SCM_TSTAMP_ACK for the first chunk should be received at t=20ms.
+0 recvmsg(4, {msg_name(...)=...,
msg_iov(1)=[{...,0}],
msg_flags=MSG_ERRQUEUE|MSG_TRUNC,
msg_control=[
{cmsg_level=SOL_SOCKET,
cmsg_type=SCM_TIMESTAMPING,
cmsg_data={scm_sec=0,scm_nsec=20000000}},
{cmsg_level=CMSG_LEVEL_IP,
cmsg_type=CMSG_TYPE_RECVERR,
cmsg_data={ee_errno=ENOMSG,
ee_origin=SO_EE_ORIGIN_TIMESTAMPING,
ee_type=0,
ee_code=0,
ee_info=SCM_TSTAMP_ACK,
ee_data=1999}}
]}, MSG_ERRQUEUE) = 0
// SCM_TSTAMP_ACK for the second chunk should be received at t=30ms.
+0 recvmsg(4, {msg_name(...)=...,
msg_iov(1)=[{...,0}],
msg_flags=MSG_ERRQUEUE|MSG_TRUNC,
msg_control=[
{cmsg_level=SOL_SOCKET,
cmsg_type=SCM_TIMESTAMPING,
cmsg_data={scm_sec=0,scm_nsec=30000000}},
{cmsg_level=CMSG_LEVEL_IP,
cmsg_type=CMSG_TYPE_RECVERR,
cmsg_data={ee_errno=ENOMSG,
ee_origin=SO_EE_ORIGIN_TIMESTAMPING,
ee_type=0,
ee_code=0,
ee_info=SCM_TSTAMP_ACK,
ee_data=3999}}
]}, MSG_ERRQUEUE) = 0

23
tools/testing/selftests/net/packetdrill/tcp_ts_recent_fin_tsval.pkt Normal file
View File

@ -0,0 +1,23 @@
// SPDX-License-Identifier: GPL-2.0
// Test that we send FIN packet with correct TSval
--tcp_ts_tick_usecs=1000
--tolerance_usecs=7000
`./defaults.sh`
// Create a socket.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
// Establish a connection.
+0 < S 0:0(0) win 20000 <mss 1000,sackOK,TS val 100 ecr 0>
+0 > S. 0:0(0) ack 1 <mss 1460,sackOK,TS val 100 ecr 100>
+.1 < . 1:1(0) ack 1 win 20000 <nop,nop,TS val 200 ecr 100>
+0 accept(3, ..., ...) = 4
+1 close(4) = 0
// Check that FIN TSval is updated properly, one second has passed since last sent packet.
+0 > F. 1:1(0) ack 1 <nop,nop,TS val 1200 ecr 200>

25
tools/testing/selftests/net/packetdrill/tcp_ts_recent_invalid_ack.pkt Normal file
View File

@ -0,0 +1,25 @@
// SPDX-License-Identifier: GPL-2.0
// Test that we reject TS val updates on a packet with invalid ACK sequence
`./defaults.sh
`
// Create a socket.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
// Establish a connection.
+.1 < S 0:0(0) win 20000 <mss 1000,sackOK,TS val 100 ecr 0>
+0 > S. 0:0(0) ack 1 <mss 1460,sackOK,TS val 100 ecr 100>
+.1 < . 1:1(0) ack 1 win 20000 <nop,nop,TS val 200 ecr 100>
+0 accept(3, ..., ...) = 4
// bad packet with high tsval (its ACK sequence is above our sndnxt)
+0 < F. 1:1(0) ack 9999 win 20000 <nop,nop,TS val 200000 ecr 100>
+0 < . 1:1001(1000) ack 1 win 20000 <nop,nop,TS val 201 ecr 100>
+0 > . 1:1(0) ack 1001 <nop,nop,TS val 200 ecr 201>

25
tools/testing/selftests/net/packetdrill/tcp_ts_recent_reset_tsval.pkt Normal file
View File

@ -0,0 +1,25 @@
// SPDX-License-Identifier: GPL-2.0
// Test that we send RST packet with correct TSval
--tcp_ts_tick_usecs=1000
`./defaults.sh`
// Create a socket.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
// Establish a connection.
+0 < S 0:0(0) win 20000 <mss 1000,sackOK,TS val 100 ecr 0>
+0 > S. 0:0(0) ack 1 <mss 1460,sackOK,TS val 100 ecr 100>
+.1 < . 1:1(0) ack 1 win 20000 <nop,nop,TS val 200 ecr 100>
+0 accept(3, ..., ...) = 4
+0 < . 1:1001(1000) ack 1 win 20000 <nop,nop,TS val 201 ecr 100>
+0 > . 1:1(0) ack 1001 <nop,nop,TS val 200 ecr 201>
+1 close(4) = 0
// Check that RST TSval is updated properly, one second has passed since last sent packet.
+0 > R. 1:1(0) ack 1001 <nop,nop,TS val 1200 ecr 201>

37
tools/testing/selftests/net/packetdrill/tcp_user_timeout_user-timeout-probe.pkt Normal file
View File

@ -0,0 +1,37 @@
// SPDX-License-Identifier: GPL-2.0
`./defaults.sh`
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0 < S 0:0(0) win 0 <mss 1460>
+0 > S. 0:0(0) ack 1 <mss 1460>
+.1 < . 1:1(0) ack 1 win 65530
+0 accept(3, ..., ...) = 4
+0 setsockopt(4, SOL_TCP, TCP_USER_TIMEOUT, [3000], 4) = 0
+0 write(4, ..., 24) = 24
+0 > P. 1:25(24) ack 1
+.1 < . 1:1(0) ack 25 win 65530
+0 %{ assert tcpi_probes == 0, tcpi_probes; \
assert tcpi_backoff == 0, tcpi_backoff }%
// install a qdisc dropping all packets
+0 `tc qdisc delete dev tun0 root 2>/dev/null ; tc qdisc add dev tun0 root pfifo limit 0`
+0 write(4, ..., 24) = 24
// When qdisc is congested we retry every 500ms
// (TCP_RESOURCE_PROBE_INTERVAL) and therefore
// we retry 6 times before hitting 3s timeout.
// First verify that the connection is alive:
+3.250 write(4, ..., 24) = 24
// Now verify that shortly after that the socket is dead:
+.100 write(4, ..., 24) = -1 ETIMEDOUT (Connection timed out)
+0 %{ assert tcpi_probes == 6, tcpi_probes; \
assert tcpi_backoff == 0, tcpi_backoff }%
+0 close(4) = 0

32
tools/testing/selftests/net/packetdrill/tcp_user_timeout_user_timeout.pkt Normal file
View File

@ -0,0 +1,32 @@
// SPDX-License-Identifier: GPL-2.0
`./defaults.sh`
// Initialize connection
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
+0 < S 0:0(0) win 32792 <mss 1000,sackOK,nop,nop>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,nop,sackOK>
+.1 < . 1:1(0) ack 1 win 32792
+0 accept(3, ..., ...) = 4
// Okay, we received nothing, and decide to close this idle socket.
// We set TCP_USER_TIMEOUT to 3 seconds because really it is not worth
// trying hard to cleanly close this flow, at the price of keeping
// a TCP structure in kernel for about 1 minute !
+2 setsockopt(4, SOL_TCP, TCP_USER_TIMEOUT, [3000], 4) = 0
+0 close(4) = 0
+0 > F. 1:1(0) ack 1
+.3~+.400 > F. 1:1(0) ack 1
+.3~+.400 > F. 1:1(0) ack 1
+.6~+.800 > F. 1:1(0) ack 1
// We finally receive something from the peer, but it is way too late
// Our socket vanished because TCP_USER_TIMEOUT was really small
+0 < . 1:2(1) ack 1 win 32792
+0 > R 1:1(0)

24
tools/testing/selftests/net/packetdrill/tcp_validate_validate-established-no-flags.pkt Normal file
View File

@ -0,0 +1,24 @@
// SPDX-License-Identifier: GPL-2.0
// Verify that established connections drop a segment without the ACK flag set.
`./defaults.sh`
// Create a socket.
0 socket(..., SOCK_STREAM, IPPROTO_TCP) = 3
+0 setsockopt(3, SOL_SOCKET, SO_REUSEADDR, [1], 4) = 0
+0 bind(3, ..., ...) = 0
+0 listen(3, 1) = 0
// Establish a connection.
+0 < S 0:0(0) win 20000 <mss 1000,sackOK,nop,nop>
+0 > S. 0:0(0) ack 1 <mss 1460,nop,nop,sackOK>
+.01 < . 1:1(0) ack 1 win 20000
+0 accept(3, ..., ...) = 4
// Receive a segment with no flags set, verify that it's not enqueued.
+.01 < - 1:1001(1000) win 20000
+0 ioctl(4, SIOCINQ, [0]) = 0
// Receive a segment with ACK flag set, verify that it is enqueued.
+.01 < . 1:1001(1000) ack 1 win 20000
+0 ioctl(4, SIOCINQ, [1000]) = 0